Terbilang Excel Dalam Format Angka Desimal dan Rupiah

Terbilang Excel Dalam Format Angka Desimal dan Rupiah

Cara membuat rumus terbilang rupiah excel dengan angka di belakang koma (desimal)
Terbilang Excel Dalam Format Angka Desimal dan Rupiah

Terbilang Angka Rupiah dan Desimal - Tutorial microsoft excel kali ini merupakan lanjutan tutorial sebelumnya tentang "Add-In Kombinasi Terbilang Excel".

Pada tutorial ini akan dijelaskan bagaimana menambahkan teks "Rupiah" pada rumus terbilang, juga cara mengubah kapitalisasi huruf serta cara menggunakan rumus terbilang pada bilangan desimal dengan agka dibelakang koma.

Sebelum meneruskan membaca, sebaiknya anda baca dulu halaman tersebut.

Jika sudah Anda baca, pastikan juga add-In terbilang yang bisa Anda download pada halaman tersebut sudah terpasang dengan benar dan dapat digunakan.

Cara Menambahkan Teks Rupiah Pada Rumus Terbilang Excel

Untuk menambahkan teks rupiah pada akhir rumus terbilang angka rupiah cukup mudah. Bisa menggunakan operator ampersand (&) seperti berikut:

=terbilang(Angka)&" rupiah"

Selain dengan operator "&" bisa juga menggunakan fungsi CONCATENATE:

=CONCATENATE(terbilang(Angka);" rupiah")

Lebih detail mengenai cara menggabungkan teks excel bisa Anda pelajari pada halaman berikut: Cara Mudah Menggabungkan Teks di Excel.

Mengubah Kapitalisasi Rumus Terbilang Excel

Untuk mengubah kapitalisasi huruf terbilang excel, gunakan fungsi Upper, Lower atau Proper yang sudah disediakan excel.

Perhatikan contoh gambar penggunaan rumus terbilang angka rupiah berikut :

Contoh Penggunaan Add-In Terbilang Excel

Dari Contoh tersebut bisa anda lihat, bahwa untuk merubah format besar kecil huruf adalah dengan menambahkan Fungsi-fungsi Teks Excel pada fungsi terbilang excel. Sehingga rumus excelnya menjadi seperti berikut:

=UPPER(terbilang(B5))
=PROPER(terbilangeng(B5))
=LOWER(akk(B5))
=UPPER(akkeng(B5))

Jika anda lebih teliti ternyata Add-In terbilang ini memiliki masalah kompatibilitas dengan angka desimal. Contoh nomor 5 hasil akhirnya semestinya "Sembilan Milliar Sembilanratus Sembilanpuluh Sembilan koma Empatpuluh Lima".

Add-In ini ternyata tidak bekerja untuk angka di belakang koma. Untuk mengatasi masalah ini, seperti yang sudah saya singgung pada tutorial sebelumnya yakni dengan menggunakan Fungsi-fungsi pembulatan Excel.

Kita lanjuutkan pembahasan mengenai hal ini pada bagian selanjutnya.

Rumus Terbilang Excel Dengan Koma (Desimal)

Cara penulisan terbilang rupiah dengan koma jika Anda menggunakan Addin terbilang yang tidak mendukung nilai angka dibelakang koma (bilangan desimal) adalah dengan memisahkan dulu antara angka di depan koma dan angka yang ada di belakang koma. Kemudian gunakan fungsi terbilang pada masing-masing bagian.

Rumus umumnya sebagai berikut:

=terbilang(Angka_Depan)&" koma "&terbilang(Angka_Belakang)

Misalnya angka desimal dengan dua angka dibelakang koma 80,78. Pada rumus terbilang excel, pisahkan dulu Angka 80 sebagai Angka_Depan koma dan angka 78 sebagai Angka_Belakang koma.

Bagaimana cara memisahkannya?

Pembahasan khusus mengenai cara mengambil angka di depan koma bisa Anda pelajari pada halmaan berikut: Rumus Menghilangkan Angka di Belakang Koma.

Sedangkan untuk mengambil angka di belakang koma yakni dengan cara mengurangi nilai Asli dengan nilai angka depan koma tadi.

Sebagai contoh, kita akan menggunakan fungsi Rounddown dan INT pada rumus terbilang excel.

Terbilang Excel Desimal Dengan Fungsi ROUNDDOWN

Fungsi ROUNDDOWN digunakan untuk membulatkan angka ke bawah
Terbilang Excel Dalam Format Angka Desimal dan Rupiah

Dalam contoh ini angka yang akan kita proses adalah 123,45 dengan dua angka dibelakang koma.

  1. Bulatkan angka depan koma dengan dengan rumus excel berikut:
    =ROUNDDOWN(B2;0)
  2. Ambil dan bulatkan angka dibelakang koma dengan rumus excel berikut:
    =ROUNDDOWN(10^2*(B2-B3);0)
  3. 10^2 dimaksudkan untuk mengambil 2 angka dibelakang koma (100*0,45) jika yang dikehendaki 3 angka koma pakai 10^3
  4. Rumus Terbilang Excel angka depan koma rumus terbilangnya adalah:
    =terbilang(ROUNDDOWN(B2;0))
  5. Rumus Terbilang Excel angka dibelakang koma adalah:
    =terbilang(ROUNDDOWN(10^2*(B2-B3);0))
  6. Gabung rumus-rumus excel tersebut dengan menambahkan teks koma ditantara keduanya sehingga rumus excelnya menjadi:
    =terbilang(ROUNDDOWN(B2;0))&" Koma "&terbilang(ROUNDDOWN(10^2*(B2-B3);0))
  7. Jika menghendaki ada tulisan rupiah di belakang hasil fungsi terbilang rumusnya menjadi:
    =terbilang(ROUNDDOWN(B2;0))&" Koma "&terbilang(ROUNDDOWN(10^2*(B2-B3);0))&" Rupiah"

Dalam prakteknya mungkin anda akan meghendaki angka-angka tersebut tidak kita pisah satu persatu dalam banyak sel.

Jika demikian maka rumusnya akan menjadi:

=terbilang(ROUNDDOWN(B2;0))&" Koma "&terbilang(ROUNDDOWN(10^2*(B2-ROUNDDOWN(B2;0));0))&" Rupiah"

Terbilang Excel Desimal Dengan Fungsi INT

Fungsi INT digunakan untuk membulatkan angka ke bawah dalam bilangan bulat terdekat.
Terbilang Excel Dalam Format Angka Desimal dan Rupiah

Langkah-langkah menggunakan fungsi INT dalam kasus angka desimal untuk fungsi terbilang excel ini sebenarnya sama dengan menggunakan fungsi ROUNDDOWN.

  1. Bulatkan angka dengan dengan rumus excel
    =INT(B2)
  2. Ambil dan bulatkan angka dibelakang koma dengan rumus excel
    =INT(10^2*(B2-B3))
  3. 10^2 dimaksudkan untuk mengambil 2 angka dibelakang koma (100*0,45) jika yang dikehendaki 3 angka koma pakai 10^3
  4. Rumus Terbilang Excel angka depan rumus terbilangnya
    =terbilang(INT(B2))
  5. Rumus Terbilang Excel angka dibelakang koma
    =terbilang(INT(10^2*(B2-B3)))
  6. Gabung rumus-rumus excel tersebut dengan menambahkan teks koma ditantara keduanya sehingga rumus excelnya menjadi
    =terbilang(INT(B2))&" Koma "&terbilang(INT(10^2*(B2-B3)))
  7. Jika menghendaki ada tulisan rupiah di belakang hasil fungsi terbilang rumusnya menjadi
    =terbilang(INT(B2))&" Koma "&terbilang(INT(10^2*(B2-B3)))&" Rupiah"

Jika digabungkan dalam satu sel maka rumusnya akan menjadi

=terbilang(INT(B2))&" Koma "&terbilang(INT(10^2*(B2-INT(B2))))&" Rupiah"

Dengan sedikit kreatifitas anda bisa menggunakan fungsi akk dan penambahan satuan rupiah dan sen jika diperlukan.

Yang membedakan Fungsi ROUNDDOWN dan INT adalah argument dari kedua fungsi tersebut.

Di sini saya tidak akan membahas hal tersebut karena argumen-argumen fungsi tersebut sudah saya bahas tersendiri pada halaman-halaman penjelasan masing-masing fungsi.

Selain menggunakan addin terbilang seperti diatas merubah engka ke huruf atau kata teks bisa juga dilakukan dengan menggunakan rumus excel. Caranya bisa anda baca pada tautan berikut: Rumus Terbilang Excel Manual Tanpa Macro Untuk Merubah Angka Menjadi Huruf

Khusus untuk nilai 1-100 yang biasanya digunakan untuk mengkonversi nilai menjadi terbilang huruf atau kata bisa juga dilakukan dengan rumus Vlookup. Silahkan baca tutorialnya di laman ini: Rumus Terbilang Manual Dengan Fungsi Vlookup Excel

Jika ada pertanyaan, saran atau kritik, silakan tulis di kotak komentar di bawah ini. Dan bagikan tulisan ini di akun sosial media Anda supaya teman-teman Anda juga bisa mendapatkan manfaat yang sama.

LANGGANAN GRATIS!

Dapatkan update tutorial excel gratis langsung ke email anda.