Rumus Vlookup Dengan 2 Kriteria di Excel

Cara menggunakan rumus vlookup dengan 2 kriteria, kondisi atau parameter di excel (Vlookup 2 kolom berbeda & rumus gabungan Vlookup-IF/Vlookup-Match)

Vlookup 2 kriteria - Pada dasarnya fungsi atau rumus Vlookup excel hanya bisa melakukan pencarian data dengan 1 kriteria atau 1 kata kunci. Itupun dengan syarat bahwa data yang dicari berada di kolom pertama tabel referensi pencarian.

Lalu bagaimana jika kita menghendaki melakukan Vlookup data dengan 2 kriteria, kondisi, syarat, parameter atau vlookup dengan 2 kata kunci?

Dengan sedikit kreatifitas, sebenarnya vlookup juga bisa digunakan untuk melakukan pencarian data dengan multi kriteria. Namun sebelum itu anda perlu untuk memahami cara menggunakan rumus Vlookup excel terlebih dahulu.

Jika sudah silahkan melanjutkan untuk membaca tutorial excel berikut:

Rumus Vlookup 2 Kriteria Pada 2 Kolom

Pada contoh kasus ini fungsi Vlookup excel digunakan untuk melakukan pencarian data dengan 2 kriteria yang mana 2 parameter kriteria atau 2 kata kunci pencarian yang digunakan berada pada 2 kolom yang berbeda.

Contoh Kasus Rumus Vlookup Dengan 2 Kriteria

Pada kasus diatas bagaimanakah cara mencari jumlah sumbangan yang diberikan oleh Gunawan dari RT 2?

Jadi pada kasus diatas kita ingin melakukan VLookup dengan kriteria berada pada kolom 1 dan kolom 2 dan mengambil data yang sebaris pada kolom 3.

Untuk menyelesaikan kasus ini dengan fungsi Vlookup anda perlu membuat sebuah kolom dummy (kolom bantu) di sebelah kiri tabel referensi sumber data. Kemudian gabungkan teks pada setiap baris pada kolom 1 dan kolom 2 menjadi 1 kriteria unik sebagai acuan pencarian untuk fungsi Vlookup Excel.

Contoh Kasus Rumus Vlookup Dengan 2 Kondisi

Pada contoh diatas saya kolom dummy diletakkan pada kolom A dengan rumus excel pada sel A3:

=B3&C3

Kemudian copy paste rumus tersebut ke sel-sel lain dibawahnya.

Dengan rumus tersebut maka pada kolom A akan terisi data unik gabungan dari kolom Nama dan RT, sehingga bisa kita jadikan acuan pencarian untuk rumus Vlookup.

Setelah membuat kolom dummy tersebut maka kita bisa menggunakan fungsi Vlookup Excel untuk melakukan pencarian data jumlah sumbangan pada sel G4 dengan 2 parameter NAMA(G2) dan RT(G3).

Contoh Kasus Rumus Vlookup Dengan 2 Kolom

Sintaks fungsi Vlookup adalah sebagai berikut:

VLOOKUP(NilaiYangDiCari; TabelReferensi; NomorKolom; [RangeLookup])

Untuk penjelasan sintaks diatas bisa anda baca pada tutorial belajar excel sebelumnya: Cara Menggunakan Rumus VLookup Excel

Rumus Vlookup yang digunakan pada sel G4 adalah:

=VLOOKUP(G2&G3;A2:D11;4;FALSE)

Jika sudah berhasil maka kolom dummy pada kolom A pada contoh tersebut bisa anda sembunyikan.

Jika tidak menghendaki kolom bantu, solusi lain adalah dengan menggunakan rumus array gabungan fungsi index dan match yang bisa anda baca di : Cara Lookup Banyak Kriteria dengan INDEX dan MATCH.

Rumus Vlookup 2 Kriteria Pada 1 Kolom Dan 1 Baris

Jika kriteria tidak berada pada 2 kolom yang berbeda, namun berada pada kolom dan baris, misal kriteria pertama berbentuk kolom dan kriteria kedua berada pada baris judul tabel. Bagaimana rumus Vlookupnya?

Untuk kasus ini contoh datanya seperti berikut:

Contoh Kasus Rumus Vlookup Dengan Kriteria Kolom dan Baris

Pada contoh diatas bagaimakah rumus Vlookupnya untuk mengetahui jumlah stok meja pada gudang 2?

Untuk kasus diatas sebenarnya bukan kasus Vlookup multi kriteria, Vlookup pada contoh kasus ini hanya menggunakan 1 parameter kriteria yakni "Nama Barang". Hanya saja posisi kolom yang ingin diambil berbeda sesuai lokasi gudang yang dikehendaki.

Ada beberapa rumus excel yang bisa anda gunakan dalam kasus ini:

Rumus IF dan Vlookup

Sintaks fungsi IF adalah sebagai berikut:

IF(TesLogika; [KondisiTerpenuhi]; [KondisiTidakTerpenuhi])

Dengan menggabungkan rumus IF dan Vlookup Excel, rumus excel pada sel C12 untuk melakukan pencarian dengan 2 parameter kriteria adalah sebagai berikut:

=IF(C11="Gudang 1";VLOOKUP(C10;B2:E7;2;FALSE);IF(C11="Gudang 2";VLOOKUP(C10;B2:E7;3;FALSE);IF(C11="Gudang 3";VLOOKUP(C10;B2:E7;4;FALSE);"Gudang Tidak Ada")))

Pada rumus excel diatas fungsi Vlookup dijadikan argument untuk rumus IF Bertingkat. Sehingga kita membuat 3 rumus VLookup pada excel dengan masing-masing berbeda argumen kolomnya.

Selain memasukkan fungsi Vlookup ke dalam fungsi IF bisa juga dibalik, Fungsi IF di masukkan ke dalam fungsi Vlookup. Sehingga rumus Vlookup dan IF excelnya akan seperti ini:

=VLOOKUP(C10;B2:E7;IF(C11="Gudang 1";2;IF(C11="Gudang 2";3;IF(C11="Gudang 3";4)));FALSE)

Pada rumus excel diatas argument kolom diisi dengan fungsi IF bertingkat.

Rumus Vlookup dan Match

Selain menggunakan fungsi IF untuk menentukan kolom mana yang akan diambil oleh VLookup akan lebih mudah jika menggunakan fungsi MATCH Excel.

Untuk contoh diatas rumus Vlookup-Match excelnya adalah:

=VLOOKUP(C10;B2:E7;MATCH(C11;B2:E2;0);FALSE)

Fungsi Match Excel pada rumus vlookup ini digunakan untuk mengisi argument Kolom data mana yang akan diambil oleh fungsi Vlookup.

Pada akhirnya rumus excel mana yang anda pilih untuk melakukan Vlookup dengan 2 Kriteria atau lebih? Jika menemukan kendala atau masalah lain yang terkait dengan kasus Vlookup multi kriteria ini jangan sungkan-sungkan untuk meninggalkan komentar di bagian bawah artikel tutorial ini.

Jika dirasa bermanfaat jangan ragu-ragu untuk untuk share tutorial excel ini ke media sosial yang anda gunakan. Salam Kelas Excel.

Berikut beberapa tutorial excel lain tentang Rumus VLookup yang bisa anda pelajari: